Berke Durak [Sunday 15 June 2003] :
 >
 > Hello
 > 
 > I get the following...
 > 
 > # class toto = object method zizi = function | `Alpha -> 1 | `Beta -> 2 end;;
 > Some type variables are unbound in this type:
 >   class toto : object method zizi : [< `Alpha | `Beta] -> int end
 > The method zizi has type [< `Alpha | `Beta] -> int where .. is unbound
 > 
 > Where is the .. ? Is there no way to use polymorphic variants inside
 > classes ?

There are 3 solutions :

1) add a type constraint that "closes" the variant :

,----
| # class toto = object method zizi : [ `Alpha | `Beta] -> int =
|   function | `Alpha -> 1 | `Beta -> 2 end;;
| class toto : object method zizi : [ `Alpha | `Beta] -> int end
`----

2) add a class parameter :

,----
| # class ['a] toto = object method zizi : 'a = function | `Alpha -> 1 |
|   `Beta -> 2 end;;
| class ['a] toto :
|  object
|     constraint 'a = [< `Alpha | `Beta]
|     method zizi : 'a -> int
|   end
`----
 
3) use a polymorphic method :

,----
| # class toto = object method zizi : 'a. ([< `Alpha | `Beta] as 'a) -> int =
|   function | `Alpha -> 1 | `Beta -> 2 end ;;
| class toto : object method zizi : [< `Alpha | `Beta] -> int end
`----


About the "..", it appears in object types : 
,----
| # class titi = object method a o = o#b end ;;
| 
| Characters 5-40:
|   class titi = object method a o = o#b end ;;
|        ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
| Some type variables are unbound in this type:
|   class titi : object method a : < b : 'a; .. > -> 'a end
| The method a has type < b : 'a; .. > -> 'a where .. is unbound
`----

It's the same problem with polymorphic variants, there's an implicit
type variable that must be bound in the class definition.

-- 
   Olivier

-------------------
To unsubscribe, mail caml-list-request@inria.fr Archives: http://caml.inria.fr
Bug reports: http://caml.inria.fr/bin/caml-bugs FAQ: http://caml.inria.fr/FAQ/
Beginner's list: http://groups.yahoo.com/group/ocaml_beginners