---

6.4 Type expressions

typexpr	::=	' ident
	|	_
	|	( typexpr )
	|	[[?]label-name:]  typexpr ->  typexpr
	|	typexpr  { * typexpr }+
	|	typeconstr
	|	typexpr  typeconstr
	|	( typexpr  { , typexpr } )  typeconstr
	|	typexpr as '  ident
	|	variant-type
	|	< [..] >
	|	< method-type  { ; method-type }  [; ..] >
	|	# class-path
	|	typexpr #  class-path
	|	( typexpr  { , typexpr } ) #  class-path
poly-typexpr	::=	typexpr
	|	{ ' ident }+ .  typexpr
method-type	::=	method-name :  poly-typexpr

The table below shows the relative precedences and associativity of operators and non-closed type constructions. The constructions with higher precedences come first.

Operator	Associativity
Type constructor application	--
*	--
->	right
as	--

Type expressions denote types in definitions of data types as well as in type constraints over patterns and expressions.

Type variables

The type expression ' ident stands for the type variable named ident. The type expression _ stands for an anonymous type variable. In data type definitions, type variables are names for the data type parameters. In type constraints, they represent unspecified types that can be instantiated by any type to satisfy the type constraint. In general the scope of a named type variable is the whole enclosing definition; they can only be generalized when leaving this scope. Anonymous variables have no such restriction.

Parenthesized types

The type expression ( typexpr ) denotes the same type as typexpr.

Function types

The type expression typexpr₁ ->  typexpr₂ denotes the type of functions mapping arguments of type typexpr₁ to results of type typexpr₂.

label-name :  typexpr₁ ->  typexpr₂ denotes the same function type, but the argument is labeled label.

optlabel  typexpr₁ ->  typexpr₂ denotes the type of functions mapping an optional labeled argument of type typexpr₁ to results of type typexpr₂. That is, the physical type of the function will be typexpr₁ option ->  typexpr₂.

Tuple types

The type expression typexpr₁ * ... *  typexpr_n denotes the type of tuples whose elements belong to types typexpr₁, ...  typexpr_n respectively.

Constructed types

Type constructors with no parameter, as in typeconstr, are type expressions.

The type expression typexpr  typeconstr, where typeconstr is a type constructor with one parameter, denotes the application of the unary type constructor typeconstr to the type typexpr.

The type expression (typexpr₁,..., typexpr_n)  typeconstr, where typeconstr is a type constructor with n parameters, denotes the application of the n-ary type constructor typeconstr to the types typexpr₁ through typexpr_n.

Aliased and recursive types

The type expression typexpr as '  ident denotes the same type as typexpr, and also binds the type variable ident to type typexpr both in typexpr and in the remaining part of the type. If the type variable ident actually occurs in typexpr, a recursive type is created. Recursive types for which there exists a recursive path that does not contain an object or variant type constructor are rejected, except when the -rectypes mode is selected.

If ' ident denotes an explicit polymorphic variable, and typexpr denotes either an object or variant type, the row variable of typexpr is captured by ' ident, and quantified upon.

Variant types

variant-type	::=	[ [ | ] tag-spec  { | tag-spec } ]
	|	[> [ tag-spec ]  { | tag-spec } ]
	|	[< [ | ] tag-spec-full  { | tag-spec-full }  [ > { `tag-name }+ ] ]
tag-spec	::=	`tag-name  [ of typexpr ]
	|	typexpr
tag-spec-full	::=	`tag-name  [ of typexpr ]  { & typexpr }
	|	typexpr

Variant types describe the values a polymorphic variant may take.

The first case is an exact variant type: all possible tags are known, with their associated types, and they can all be present. Its structure is fully known.

The second case is an open variant type, describing a polymorphic variant value: it gives the list of all tags the value could take, with their associated types. This type is still compatible with a variant type containing more tags. A special case is the unknown type, which does not define any tag, and is compatible with any variant type.

The third case is a closed variant type. It gives information about all the possible tags and their associated types, and which tags are known to potentially appear in values. The above exact variant type is just an abbreviation for a closed variant type where all possible tags are also potentially present.

In all three cases, tags may be either specified directly in the `tag-name [...] form, or indirectly through a type expression. In this last case, the type expression must expand to an exact variant type, whose tag specifications are inserted in its place.

Full specification of variant tags are only used for non-exact closed types. They can be understood as a conjunctive type for the argument: it is intended to have all the types enumerated in the specification.

Such conjunctive constraints may be unsatisfiable. In such a case the corresponding tag may not be used in a value of this type. This does not mean that the whole type is not valid: one can still use other available tags.

Object types

An object type < method-type  { ; method-type } > is a record of method types.

Each method may have an explicit polymorphic type: { ' ident }⁺ .  typexpr. Explicit polymorphic variables have a local scope, and an explicit polymorphic type can only be unified to an equivalent one, with polymorphic variables at the same positions.

The type < method-type  { ; method-type } ; .. > is the type of an object with methods and their associated types are described by method-type₁, ...,  method-type_n, and possibly some other methods represented by the ellipsis. This ellipsis actually is a special kind of type variable (also called row variable in the literature) that stands for any number of extra method types.

#-types

The type # class-path is a special kind of abbreviation. This abbreviation unifies with the type of any object belonging to a subclass of class class-path. It is handled in a special way as it usually hides a type variable (an ellipsis, representing the methods that may be added in a subclass). In particular, it vanishes when the ellipsis gets instantiated. Each type expression # class-path defines a new type variable, so type # class-path -> #  class-path is usually not the same as type (# class-path as '  ident) -> '  ident.

Use of #-types to abbreviate variant types is deprecated. If t is an exact variant type then #t translates to [< t], and #t[> `tag<sub>1</sub> ...`tag_k] translates to [< t > `tag<sub>1</sub> ...`tag_k]

Variant and record types

There are no type expressions describing (defined) variant types nor record types, since those are always named, i.e. defined before use and referred to by name. Type definitions are described in section 6.8.1.

---